In the following picture, you see a list of names, many of which are repeated 2, 3, or more times. Here’s how you can create a shorter list to show each unique item only once.



To create a list of unique names in column C based on the list of many repeated names in column A, follow these 3 steps:

Step 1
Select any single cell in the list. In the above picture, cell A1 is selected.

Step 2
From your keyboard, press the Alt key, and while doing so, press the D and F keys. Then, press the A key as shown in the next picture.



Step 3
You will see the Advanced Filter dialog box as shown below. Click to select the options for “Copy to another location” and “Unique records only”. In the Copy to field, you see that $C$1 is entered, which you can type in manually, or click into that field and then click cell C1. After that, click OK.



And that’s it! Your list of unique items will be shown in column C similar to the next picture.

What is today’s date, and what is the current time of day? Here, you create a Web query to import a display of the current day and time for several North American time zones.



I came up with this solution out of necessity a few years ago while developing a client project that called for no changes to be allowed in workbooks after certain dates and times. Some users were circumventing the rule by changing the system clock on their computers, so I used a reliable, external source by which to programmatically monitor actual dates and times.

You access the website to the United States Naval Observatory, where the day and time are recorded on the Master Clock of the United States Navy. The Web query will place the information onto Sheet1 from a macro named TimeAfterTime, similiar to what is shown in the above picture..

Sub TimeAfterTime()

'Open a With structure for the destination worksheet.
With Worksheets("Sheet1")

'Declare a String type variable for the web site address.
Dim strURL As String
'Define the web site address, from which the information
'will be imported to your worksheet.
strURL = "http://tycho.usno.navy.mil/cgi-bin/timer.pl"

'For consistency, I prefer to activate the worksheet
'that will receive the web data.
'Cell A1 is a convenient cell to situate yourself.
Application.Goto .Range("A1"), True

'Clear the cells in the worksheet so you know the data
'being imported will not be confused with other data
'you may have imported previously and not yet deleted.
Cells.Clear

'Open a With structure for the Add method of your new
'Query Table. The connection, URL, and destination sheet,
'and other information that follows, must be specified.
With .QueryTables.Add _
(Connection:="URL;" & strURL, Destination:=.Range("A1"))
.BackgroundQuery = True
.TablesOnlyFromHTML = False
.Refresh BackgroundQuery:=False
.SaveData = True
'Close the With structure of Query Table's Add method.
End With

'Close the With structure for the destination worksheet.
End With

End Sub

Here’s a macro to locate the first and last rows and columns, and the ranges being occupied by your pivottable. The (0, 0) notation after the Address property statements is to omit the look of absolute “$” references for easier readability in the MessageBox.

Sub PivotTableRangeAreas()

With ActiveSheet.PivotTables(1)

Dim TopRow1 As Long, TopRow2 As Long, LastRow As Long
Dim LeftColumn As Long, RightColumn As Long

TopRow2 = .TableRange2.Row
With .TableRange1
TopRow1 = .Row
LastRow = .Rows.Count + .Row - 1
LeftColumn = .Column
RightColumn = .Columns.Count + .Column - 1
End With

MsgBox "The pivot table named " & .Name & vbCrLf & _
"occupies these range elements:" & vbCrLf & vbCrLf & _
"With the Report (Page) field: " & vbCrLf & _
.TableRange2.Address(0, 0) & vbCrLf & _
"Without the Report (Page) field: " & vbCrLf & _
.TableRange1.Address(0, 0) & vbCrLf & vbCrLf & _
"First row, with the Report (Page) field: " & TopRow2 & vbCrLf & _
"First row, without the Report (Page) field: " & TopRow1 & vbCrLf & _
"Last row: " & LastRow & vbCrLf & _
"Left column: " & LeftColumn & vbCrLf & _
"Right column: " & RightColumn, , "Pivot table location."

End With

End Sub

Here’s a video explaining what array formulas are, how to enter them, and a look behind the scenes to show how and why they work. Array formulas are a different animal, requiring extra care to understand how, when, and why it’s a good idea to use them.

As the video explains, an array is simply a collection of items. The items can be cell values (as this video demonstrates), or the items can be some other kind of data that Excel holds in memory, and then acts upon when called to do so.

An array formula is a special kind of formula that can perform multiple calculations simultaneously, on one or more items in the array.

There are two kinds of array formulas. They can return one value in one cell, as this video tip shows, or they can return several values in several cells, which I’ll cover in future video tips.

In the video, a range of data that is potentially hundreds of thousands of rows deep contains two columns whose pairs of numbers are being multipied with each other, then summed, all by a single array formula. This bypasses the need for helper formulas in another column, meaning a single array formula is doing the work of hundreds of thousands of non-array formulas.

In edit mode of any formula — and it’s shown with the array formulas in the video — you can select the arguments within the SUM function’s parentheses, press the F9 key, and observe how the array formula calculates and stores its items to display the final result you see in the cell.

Take some time to understand the basic logic of array formula construction. You’ll find array formulas to be a valuable tool in your Excel problem-solving set of skills.

In January I posted this example for using AutoFilter for dates. AutoFilter is usually quicker and more efficient but I wanted to show how an example of looping through dates by their year.

Here’s a collection of VBA examples, all rolled into this one macro, to demonstrate:
• Using an InputBox with default argument.
• Looping.
• Identifying dates by their year.
• Copying rows to another sheet.
• Programmatically entering a dynamic formula.

In the first picture is a list of sales activity during a mishmash of various years. You provide an InputBox for the user to ferret out any particular year to be copied to Sheet2, and enter a dynamic SUM for the Income, Expense, and Net totals.



The second picture shows a result if year 2010 was entered in the InputBox, with a SUM formula selected that the macro produced.



Here is the macro with explanatory comments in green.

Sub CopyYear()

'Declare a String variable for the Year.
Dim strYear as String
'InputBox to ask for a Year number, default example 2010.
strYear = _
InputBox("Enter the four-digit year:", "Copy a year of data", "2010")

'If no year is entered or Cancel is clicked, exit sub.
If strYear = "" Then
MsgBox "You did not enter a year.", , "Cancelled."
Exit Sub
End If

'If the InputBox entry is not a four-digit number exit sub.
If Len(strYear) <> 4 Or IsNumeric(CStr(strYear)) = False Then
MsgBox "You need to enter a four-digit year," & vbCrLf & _
"example, 2010.", 48, "Not a valid entry."
Exit Sub
End If

'All reasonable precautions are complete.

'Turn off ScreenUpdating.
Application.ScreenUpdating = False

'Declare variables for row, last row, and cell range.
Dim xRow As Long, LastRow As Long, cell As Range
'Define xRow as 2 as the destination first row on Sheet2.
'Row 1 on Sheet2 will have header labels.
xRow = 2

'Open a With structure for Sheet2.
With Sheets("Sheet2")
'Clear all the cells on Sheet2 to start with a clean sheet.
.Cells.Clear
'Put your column headers on row 1 of Sheet2.
.Range("A1:E1").Value = _
Array("Widget ID", "Date", "Income", "Expenses", "Net")

'Open a For Each loop to examine each Constant cell (shorthand #2).
'in column B which is written as Columns(2).
For Each cell In Columns(2).SpecialCells(2)
'First, evaluate for the cell value being a date.
If IsDate(cell.Value) = True Then
'Next, evaluate the date being the same year as entered in the InputBox.
If Year(cell.Value) = strYear Then
'If the evaluations are True, copy that row to the next available row
'in Sheet2 by using the xRow variable.
Rows(cell.Row).Copy .Rows(xRow)
'Add a 1 to the xRow variable to identify the next available row,
'for the next True evaluation.
xRow = xRow + 1
End If
End If
Next cell

'Identify the last row of copied data on Sheet2.
LastRow = .Cells(Rows.Count, 1).End(xlUp).Row

'Enter header labels for totals.
.Range("G1:I1").Value = Array("Income", "Expenses", "Net")

'Place the SUM function in G2 for Income total from column C.
.Range("G2").FormulaR1C1 = "=SUM(R2C3:R" & LastRow & "C3)"
'Place the SUM function in H2 for Expenses total from column D.
.Range("H2").FormulaR1C1 = "=SUM(R2C4:R" & LastRow & "C4)"
'Place the SUM function in I2 for Net total from column E.
.Range("I2").FormulaR1C1 = "=SUM(R2C5:R" & LastRow & "C5)"

'Format G2:I2 as Accounting.
.Range("G2:I2").NumberFormat = _
"_($* #,##0_);_($* (#,##0);_($* ""-""_);_(@_)"

'Autofit the columns on Sheet2 for redability.
.Columns.AutoFit

'Turn ScreenUpdating back on.
Application.ScreenUpdating = True

'Advise the user the macro is completed, or that no rows were copied
'because no dates were found matching the year entered in the InputBox.
If xRow <> 2 Then
MsgBox "All the " & strYear & " rows have been copied" & vbCrLf & _
"to Sheet2, and summed for Income, Expense, and Net.", 64, "Complete."
Else
.Cells.Clear
MsgBox "No cells in column F had dates in year " & strYear & ".", 64, "FYI"
End If

'Close With structure for Sheet2.
End With
End Sub

When you are doing calculations in cells outside of a pivot table that involve cells inside of (that is, belonging to) a pivot table, sometimes you want just the pivot table’s cell value, and other times you want the relative position and content of the cell with the GETPIVOTDATA function.

In the first picture, both examples are shown. In the first formula scenario, clicking into a pivot table cell while composing a formula in an outside cell invokes the GETPIVOTDATA function. The second formula shows the cell address (F5 in the example) that was “pointed and clicked” to help build the formula involving a pivot table cell.

There are two ways to avoid Excel forcing the GETPIVOTDATA function upon your formulas. One way is to manually type the formula without using your mouse to select the pivot table cell.

Another way is to toggle (on or off) the GETPIVOTDATA function default action. How you do that depends on your version of Excel.

In Excel versions 2003 or before, as the next picture sequence shows:
(1) From the worksheet menu, click Tools > Customize.
(2) In the Customize dialog box, select the Commands tab.
(3) In the Categories pane, select Data.
(4) In the Commands pane, select Generate GetPivotData.
(5) Use your mouse to drag the Generate GetPivotData icon to your command bar.
(6) Close the Customize dialog.
(7) As indicated by the red arrow next to the Generate GetPivotData icon you can click the icon to toggle the GetPivotData behavior on and off.

In Excel versions 2007 and after, the process is much simpler as shown below:
(1) Select any cell in the pivot table.
(2) Under PivotTable Tools, click Options > PivotTable > Options > Generate GetPivotData

Commonly accepted wisdom has it that embedded controls from the Forms toolbar cannot be programmed for events, such as can be done for ActiveX controls.

Here’s an example of a Forms List Box reacting to a double-click event.
Attached to the Forms List Box is the macro named NoDblClick.
A downloadable workbook is here.



In the worksheet module:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Run "ResetDblClick"
End Sub

In the workbook module:

Private Sub Workbook_DeActivate()
Run "ResetDblClick"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ResetDblClick"
End Sub

In a standard module:

Sub NoDblClick()
Application.OnDoubleClick = "ListBoxEexcute"
End Sub

Sub ListBoxEexcute()
If ActiveSheet.ListBoxes(Application.Caller).Name = "List Box 130" Then
Dim i As Integer
With ActiveSheet.ListBoxes("List Box 130")
For i = 1 To .ListCount
If .Selected(i) = True Then .Selected(i) = False
Next i
End With
MsgBox "Hey, I'm a Forms control and I was just double-clicked!", , _
"Forms double-click event example."
End If
End Sub

Sub ResetDblClick()
Application.OnDoubleClick = ""
End Sub

Sometimes you get data in a column which has a lot of blank cells that represent whatever text was in the last filled cell above them.

When you need to fill in hundreds or thousands of empty cells, here’s a video tip showing how to do it quickly and easily.

Here’s a developer’s approach to make things easy for your users who need to filter a range of data, based on a value they enter in a criteria cell. A Worksheet_Change event is utilized on a worksheet that is designed for this purpose, as seen in the picture. When the user enters a value in a pink cell, the table below it will be filtered on that column for that value. If the entered value does not exist in the table, a friendly message box will advise the user.

This is a worksheet level Change event procedure. To install it:
(1) Right-click on your worksheet tab and left-click to select View Code.
(2) Enter or paste the procedure into the large white area that is the worksheet module.
(3) Press Alt+Q to return to the worksheet.

Private Sub Worksheet_Change(ByVal Target As Range)

'Open With structure for Target range object.
With Target

'If the cell being changes is not A2, B2, or C2 then Exit Sub.
If Intersect(Target, Range("A2:C2")) Is Nothing Then Exit Sub
'If more than one cell is attempted to be changed then Exit Sub.
If .Cells.Count > 1 Then Exit Sub

'If the Delete key is pressed, remove AutoFilter.
If IsEmpty(Target) Then
ActiveSheet.AutoFilterMode = False
Exit Sub
End If

'Declare a String type variable for the value that was entered,
'and define the String variable.
Dim strFilter As String
strFilter = .Value
'Declare an Integer type variable for the column of the cell
'that the value was entered, and define the column.
Dim intColumn As Integer
intColumn = .Column
'Declare a Long type variable for the last used row among
'columns A, B, and C, and define that last row number.
Dim LastRow As Long
LastRow = _
Range("A:C").Find(What:="*", After:=Range("A1"), _
SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

'Close the With structure.
End With

'Do some housekeeping: delete values that may still be in the
'other criteria cells. Set EnableEvents to False and back to True.
Application.EnableEvents = False
If intColumn = 1 Then
Range("B2:C2").ClearContents
ElseIf intColumn = 2 Then
Range("A2, C2").ClearContents
Else
Range("A2:B2").ClearContents
End If
Application.EnableEvents = True

'Before attempting to filter anything, first see if the value
'that was entered exists in the relevant column.
'If it does not, end the procedure and advise the user.
If WorksheetFunction.CountIf(Range(Cells(5, intColumn), _
Cells(LastRow, intColumn)), strFilter) = 0 Then
MsgBox "This column does not contain " & strFilter, 48, "No such animal."
ActiveSheet.AutoFilterMode = False
Exit Sub
End If

'Now, all the reasonable preparations are completed.
'Execute the filter.
ActiveSheet.AutoFilterMode = False
Range(Cells(4, intColumn), _
Cells(LastRow, intColumn)).AutoFilter _
Field:=1, Criteria1:=strFilter

'As a convenience to the user, activate cell A1.
Application.Goto Range("A1"), 1

End Sub

Occasionally a parroted claim will pop up in the Excel cybersphere that resetting ScreenUpdating from False back to True in a VBA procedure is pointless and unnecessary. Supporters of this claim mistakenly believe that VBA “resets itself” at the end of a macro or procedure, and/or not resetting ScreenUpdating to True has no bad effects.

Do not believe these claims — they are misinformed and dead wrong. Whenever you set ScreenUpdating to False in your code, make certain to reset it to True. Here’s why:

First, no matter what the help files may say, or what you may have heard, ScreenUpdating does not always reset itself, including where UserForms and User Defined Functions are concerned. Part of the confusion about this topic comes from versions 2000 and before, when it was not necessary to set ScreenUpdating back to True. No longer the case starting with version 2002. Code writers who did not reset ScreenUpdating to True before 2002 had to go back to their macros and do so.

Second, resetting ScreenUpdating to True is a wise practice to cover your bases. If for example the macro errors out or is interrupted before it completes, ScreenUpdating would still be off while Excel is running. Future versions of Excel will invariably support new, or stop supporting existing, VBA methods and properties, so it’s an unnecessary risk to not reset ScreenUpdating.

Third, there might be times when you are running code in sequence and you want to see what you did while you are doing it. See the following three macros. Macros Two and Three are called by Macros One and Two, but you cannot see the results of your code until the last macro is completed, unless you had set the ScreenUpdating back to the way it was in each macro. It bears mentioning in this case that the message boxes give that wild effect if you drag them while ScreenUpdating is False, very sloppy, all the more reason to set things back to normal as you go.

Sub One()
Application.ScreenUpdating = True
MsgBox "Screen Updating is on."
Range("A1:A3").ClearContents
Range("A1").Value = "One"
Application.ScreenUpdating = False
MsgBox "Screen Updating is off now !!"
Two
End Sub

Sub Two()
Range("A2").Value = "Two"
MsgBox "ScreenUpdating is " & Application.ScreenUpdating
Three
End Sub

Sub Three()
Range("A3").Value = "Three"
MsgBox "ScreenUpdating is " & Application.ScreenUpdating
End Sub

Fourth, good code writing in my opinion involves good citizenship and an awareness of perception. If you change the setting of something, then when you are through, set it back to the way it was before. Whatever I set, I reset. Whatever I define, I undefine. You never know when the next version from Microsoft will make you wish you had the good sense to keep things in order from the start. It’s sloppy coding to not re-set what you changed. Fair or not, just as people are judged by how they write and speak, programmers are judged by the quality of their code, and seen to look lazy and VBA-ignorant when not re-setting the application.

There are too many bad possible outcomes that you would not know about until they happen. Platforms; IT settings; UDFs; fatal errors occurring from unforeseen reasons (but they’d seem obvious after they happen when first unforeseen); the list goes on. Not setting ScreenUpdating to True is a bad risk. I cannot tell you how many times in my work I’ve come across a potential bad outcome were the True setting not reset.

Whether the end of a macro comes from the expected process of events or through error handling, please always ensure you have reset ScreenUpdating to True if you had previously set to False.